Laburpena

See also

• File:Sun-Ecliptic-4Seasons-aDayOnEarth.gif
• File:Sun-Ecliptic-4Seasons-aDayOnEarth-LookingEast.gif
• File:Sun-Ecliptic-4Seasons-aDayOnEarth-LookingSouth.gif

//ecl.pov
#declare Latitude=50;
#declare Eclip=23.7;

global_settings
	{
	assumed_gamma 1.5
	noise_generator 2
	}
light_source
	{
	<-5000, 3000, -5000>, rgb <1, 1, 1>
	}
camera	{
	perspective
	location <-15, 3, 0>
	look_at <0, -.6, 0>
	}

//----------------
cylinder { // ground
	<0,0,0>,<0,0.05,0>, 7
	texture { pigment{ color rgbt<0.4,0.8,0,0.8>}
                  finish { diffuse 0.9 phong 0.5}
		}
	}
cylinder { // man
	<0,0,0>,<0,2,0>, .2
	pigment { rgb <0,0,0> }
	}

union	{
	cylinder { <0,-20,0>, <0,20,0>, 0.1	// poles axis
		pigment { rgb <1,0,0> }
		}
	torus { 7, 0.05				// Equator
		pigment { rgb <1,0,0> }
		}
	torus { 7*cos(radians(Eclip)), 0.05	// Cancer
		pigment { rgb <0,1,0> }
		translate <0,-7*sin(radians(Eclip)),0>
		}
	torus { 7*cos(radians(Eclip)), 0.05	// Capricorne
		pigment { rgb <0,1,0> }
		translate <0,7*sin(radians(Eclip)),0>
		}
	union	{
		cylinder { <0,0,0>,<0,0.05,0>, 7	// Ecliptic plane
			texture { pigment{ color rgbt<0,0.8,1,0.8>}
                		finish { diffuse 0.9 phong 0.5}
				}
			}
		sphere { <7,0,0>,.5		// Sun september
			pigment { rgb <1,1,0> }
			}
		sphere { <-7,0,0>,.5		// Sun march
			pigment { rgb <0,1,0> }
			}
		sphere { <0,0,7>,.5
			pigment { rgb <1,1,0> }
			}
		sphere { <0,0,-7>,.5
			pigment { rgb <1,1,0> }
			}
		rotate <Eclip,0,0>
		}
	rotate <0, clock, 0>
	rotate <-(90-Latitude),0,0>
	}

Lizentzia

Nik, lan honen egileak, argitaratzen dut ondorengo lizentzia hauen pean:

Fitxategi hau Creative Commons Attribution-Share Alike 3.0 Unported lizentziapean dago.

Askea zara:

• partekatzeko – lana kopiatzeko, banatzeko eta bidaltzeko
• birnahasteko – lana moldatzeko

Ondorengo baldintzen pean:

• eskuduntza – Egiletza behar bezala aitortu behar duzu, lizentzia ikusteko esteka gehitu, eta ea aldaketak egin diren aipatu. Era egokian egin behar duzu hori guztia, baina inola ere ez egileak zure lana edo zure erabilera babesten duela irudikatuz.
• berdin partekatu – Lan honetan oinarrituta edo aldatuta berria eraikitzen baduzu, emaitza lana hau bezalako lizentzia batekin argitaratu behar duzu.

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue

Baimena duzu dokumentu hau kopiatu, banatu edo/eta aldatzeko GNU Free Documentation License baldintzapean, Free Software Foundationek argitaratutako 1.2 edo ondorengo bertsioan; sekzio aldaezinik gabe, azaleko testurik gabe, eta atzeko azaleko testurik gabe. Lizentziaren kopia dago GNU Free Documentation License izenburudun atalean.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

Nahiago duzun lizentzia erabil dezakezu.